home *** CD-ROM | disk | FTP | other *** search
/ PC Gamer (Italian) 48 / PC Gamer IT CD 48 2-2.iso / Starsiege / tribesdemo.exe / Disk1 / data1.cab / Tribes_Demo / base / scripts.vol / comchat.cs < prev    next >
Encoding:
Text File  |  1999-09-14  |  4.5 KB  |  137 lines
  1. $MsgTypeSystem = 0;
  2. $MsgTypeGame = 1;
  3. $MsgTypeChat = 2;
  4. $MsgTypeTeamChat = 3;
  5. $MsgTypeCommand = 4;
  6.  
  7. function remoteSay(%clientId, %team, %message)
  8. {
  9.    %msg = %clientId @ " \"" @ escapeString(%message) @ "\"";
  10.  
  11.    // check for flooding if it's a broadcast OR if it's team in FFA
  12.    if($Server::FloodProtectionEnabled && (!$Server::TourneyMode || !%team))
  13.    {
  14.       // we use getIntTime here because getSimTime gets reset.
  15.       // time is measured in 32 ms chunks... so approx 32 to the sec
  16.       %time = getIntegerTime(true) >> 5;
  17.       if(%clientId.floodMute)
  18.       {
  19.          %delta = %clientId.muteDoneTime - %time;
  20.          if(%delta > 0)
  21.          {
  22.             Client::sendMessage(%clientId, $MSGTypeGame, "FLOOD! You cannot talk for " @ %delta @ " seconds.");
  23.             return;
  24.          }
  25.          %clientId.floodMute = "";
  26.          %clientId.muteDoneTime = "";
  27.       }
  28.       %clientId.floodMessageCount++;
  29.       // funky use of schedule here:
  30.       schedule(%clientId @ ".floodMessageCount--;", 5, %clientId);
  31.       if(%clientId.floodMessageCount > 4)
  32.       {
  33.          %clientId.floodMute = true;
  34.          %clientId.muteDoneTime = %time + 10;
  35.          Client::sendMessage(%clientId, $MSGTypeGame, "FLOOD! You cannot talk for 10 seconds.");
  36.          return;
  37.       }
  38.    }
  39.  
  40.    if(%team)
  41.    {
  42.       if($dedicated)
  43.          echo("SAYTEAM: " @ %msg);
  44.       %team = Client::getTeam(%clientId);
  45.       for(%cl = Client::getFirst(); %cl != -1; %cl = Client::getNext(%cl))
  46.          if(Client::getTeam(%cl) == %team && !%cl.muted[%clientId])
  47.             Client::sendMessage(%cl, $MsgTypeTeamChat, %message, %clientId);
  48.    }
  49.    else
  50.    {
  51.       if($dedicated)
  52.          echo("SAY: " @ %msg);
  53.       for(%cl = Client::getFirst(); %cl != -1; %cl = Client::getNext(%cl))
  54.          if(!%cl.muted[%clientId])
  55.             Client::sendMessage(%cl, $MsgTypeChat, %message, %clientId);
  56.    }
  57. }
  58.  
  59. function remoteIssueCommand(%commander, %cmdIcon, %command, %wayX, %wayY,
  60.       %dest1, %dest2, %dest3, %dest4, %dest5, %dest6, %dest7, %dest8, %dest9, %dest10, %dest11, %dest12, %dest13, %dest14)
  61. {
  62.    if($dedicated)
  63.       echo("COMMANDISSUE: " @ %commander @ " \"" @ escapeString(%command) @ "\"");
  64.    // issueCommandI takes waypoint 0-1023 in x,y scaled mission area
  65.    // issueCommand takes float mission coords.
  66.    for(%i = 1; %dest[%i] != ""; %i = %i + 1)
  67.       if(!%dest[%i].muted[%commander])
  68.          issueCommandI(%commander, %dest[%i], %cmdIcon, %command, %wayX, %wayY);
  69. }
  70.  
  71. function remoteIssueTargCommand(%commander, %cmdIcon, %command, %targIdx, 
  72.       %dest1, %dest2, %dest3, %dest4, %dest5, %dest6, %dest7, %dest8, %dest9, %dest10, %dest11, %dest12, %dest13, %dest14)
  73. {
  74.    if($dedicated)
  75.       echo("COMMANDISSUE: " @ %commander @ " \"" @ escapeString(%command) @ "\"");
  76.    for(%i = 1; %dest[%i] != ""; %i = %i + 1)
  77.       if(!%dest[%i].muted[%commander])
  78.          issueTargCommand(%commander, %dest[%i], %cmdIcon, %command, %targIdx);
  79. }
  80.  
  81. function remoteCStatus(%clientId, %status, %message)
  82. {
  83.    // setCommandStatus returns false if no status was changed.
  84.    // in this case these should just be team says.
  85.    if(setCommandStatus(%clientId, %status, %message))
  86.    {
  87.       if($dedicated)
  88.          echo("COMMANDSTATUS: " @ %clientId @ " \"" @ escapeString(%message) @ "\"");
  89.    }
  90.    else
  91.       remoteSay(%clientId, true, %message);
  92. }
  93.  
  94. function teamMessages(%mtype, %team1, %message1, %team2, %message2, %message3)
  95. {
  96.    %numPlayers = getNumClients();
  97.    for(%i = 0; %i < %numPlayers; %i = %i + 1)
  98.    {
  99.       %id = getClientByIndex(%i);
  100.       if(Client::getTeam(%id) == %team1)
  101.       {
  102.          Client::sendMessage(%id, %mtype, %message1);
  103.       }
  104.       else if(%message2 != "" && Client::getTeam(%id) == %team2)
  105.       {
  106.          Client::sendMessage(%id, %mtype, %message2);
  107.       }
  108.       else if(%message3 != "")
  109.       {
  110.          Client::sendMessage(%id, %mtype, %message3);
  111.       }
  112.    }
  113. }
  114.  
  115. function messageAll(%mtype, %message, %filter)
  116. {
  117.    if(%filter == "")
  118.       for(%cl = Client::getFirst(); %cl != -1; %cl = Client::getNext(%cl))
  119.          Client::sendMessage(%cl, %mtype, %message);
  120.    else
  121.    {
  122.       for(%cl = Client::getFirst(); %cl != -1; %cl = Client::getNext(%cl))
  123.       {
  124.          if(%cl.messageFilter & %filter)
  125.             Client::sendMessage(%cl, %mtype, %message);
  126.       }
  127.    }
  128. }
  129.  
  130. function messageAllExcept(%except, %mtype, %message)
  131. {
  132.    for(%cl = Client::getFirst(); %cl != -1; %cl = Client::getNext(%cl))
  133.       if(%cl != %except)
  134.          Client::sendMessage(%cl, %mtype, %message);
  135. }
  136.  
  137.